Notifications taking up whole screen width on Gnome 46.2 about fluent-gtk-theme

[vinceliuice]

Fixed now

[vinceliuice]

How did you installed this theme ?

[rikthomas]

Via NixOS Home Manager. I copied the default.nix from the channel repo and updated the src to get your latest commit:

fluent.nix:

{ lib
, stdenvNoCC
, fetchFromGitHub
, gitUpdater
, gnome-themes-extra
, gtk-engine-murrine
, jdupes
, sassc
, themeVariants ? [] # default: blue
, colorVariants ? [] # default: all
, sizeVariants ? [] # default: standard
, tweaks ? []
}:

let
  pname = "fluent-gtk-theme";

in
lib.checkListOfEnum "${pname}: theme variants" [ "default" "purple" "pink" "red" "orange" "yellow" "green" "teal" "grey" "all" ] themeVariants
lib.checkListOfEnum "${pname}: color variants" [ "standard" "light" "dark" ] colorVariants
lib.checkListOfEnum "${pname}: size variants" [ "standard" "compact" ] sizeVariants
lib.checkListOfEnum "${pname}: tweaks" [ "solid" "float" "round" "blur" "noborder" "square" ] tweaks

stdenvNoCC.mkDerivation rec {
  inherit pname;
  version = "latest-commit";

  src = fetchFromGitHub {
    owner = "vinceliuice";
    repo = pname;
    rev = "fdf6f8cba968909af0f45575929b13464fad3d95";
    hash = "sha256-ONhW68UUrFiv5hxkR7XI8U/5+qM+tYLIS2OM05pqJi0=";
  };

  nativeBuildInputs = [
    jdupes
    sassc
  ];

  buildInputs = [
    gnome-themes-extra
  ];

  propagatedUserEnvPkgs = [
    gtk-engine-murrine
  ];

  postPatch = ''
    patchShebangs install.sh
  '';

  installPhase = ''
    runHook preInstall

    name= HOME="$TMPDIR" ./install.sh \
      ${lib.optionalString (themeVariants != []) "--theme " + builtins.toString themeVariants} \
      ${lib.optionalString (colorVariants != []) "--color " + builtins.toString colorVariants} \
      ${lib.optionalString (sizeVariants != []) "--size " + builtins.toString sizeVariants} \
      ${lib.optionalString (tweaks != []) "--tweaks " + builtins.toString tweaks} \
      --icon nixos \
      --dest $out/share/themes

    jdupes --quiet --link-soft --recurse $out/share

    runHook postInstall
  '';

  passthru.updateScript = gitUpdater { };

  meta = with lib; {
    description = "Fluent design gtk theme";
    homepage = "https://github.com/vinceliuice/Fluent-gtk-theme";
    license = licenses.gpl3Only;
    platforms = platforms.unix;
    maintainers = [ maintainers.romildo ];
  };
}

Section from home.nix:

    gtk = {
    enable = true;
    iconTheme = {
      name = "Fluent";
      package = pkgs.fluent-icon-theme;
    };
    theme = {
      name = "Fluent-Dark";
      package = pkgs.callPackage ./fluent.nix {
        tweaks = ["blur"];
      };
    };
  };

[vinceliuice]

Does it works just run: ./install.sh to install this theme on NixOS ?

[rikthomas]

Update:
If I comment out the above (NixOS declarative way of installing the theme) and do the manual install with:

./install.sh --icon nixos --tweaks blur

it fixes the notifications but I lose the nixos panel icon. Where as the above method gets the panel icon but has the bug with the notifications still present.

[rikthomas]

Thank you so much!