stan1990 / typedlua

An Optional Type System for Lua

Typed Lua

Typed Lua is a typed superset of Lua that compiles to plain Lua. It provides optional type annotations, compile-time type checking, and class-based object oriented programming through the definition of classes, interfaces, and modules.

Requirements

lua >= 5.2.2
lpeg >= 0.12

Usage

$ tlc [options] [filename]

Compiler options

-d	    dump the AST
-g	    generate code without type checking
-h	    print this help
-o name output to file 'name' (default is 'tlc.lua')
-p	    print the AST
-v	    print current version

Major TODO list

• Add table type
• Add intersection type
• Add recursive type
• Add classes, interfaces, and modules
• Reimplement consistent-subtyping

Typed Lua Syntax

chunk ::= block
block ::= {stat} [retstat]
stat ::= ‘;’ |
varlist ‘=’ explist |
functioncall |
label |
break |
goto Name |
do block end |
while exp do block end |
repeat block until exp |
if exp then block {elseif exp then block} [else block] end |
for Name ‘=’ exp ‘,’ exp [‘,’ exp] do block end |
for namelist in explist do block end |
function funcname funcbody |
local function Name funcbody |
local namelist [‘=’ explist]
retstat ::= return [explist] [‘;’]
label ::= ‘::’ Name ‘::’
funcname ::= Name {‘.’ Name} [‘:’ Name]
varlist ::= var {‘,’ var}
var ::=  Name [‘:’ type] | prefixexp ‘[’ exp ‘]’ | prefixexp ‘.’ Name
namelist ::= Name [‘:’ type] {‘,’ Name [‘:’ type]}
explist ::= exp {‘,’ exp}
exp ::=  nil | false | true | Number | String | ‘...’ | functiondef |
prefixexp | tableconstructor | exp binop exp | unop exp
prefixexp ::= var | functioncall | ‘(’ exp ‘)’
functioncall ::=  prefixexp args | prefixexp ‘:’ Name args
args ::=  ‘(’ [explist] ‘)’ | tableconstructor | String
functiondef ::= function funcbody
funcbody ::= ‘(’ [parlist] ‘)’ [‘:’ typelist] block end
parlist ::= namelist [‘,’ ‘...’ [‘:’ type]] | ‘...’ [‘:’ type]
tableconstructor ::= ‘{’ [fieldlist] ‘}’
fieldlist ::= field {fieldsep field} [fieldsep]
field ::= ‘[’ exp ‘]’ ‘=’ exp | Name ‘=’ exp | exp
fieldsep ::= ‘,’ | ‘;’
binop ::= ‘+’ | ‘-’ | ‘*’ | ‘/’ | ‘^’ | ‘%’ | ‘..’ |
‘<’ | ‘<=’ | ‘>’ | ‘>=’ | ‘==’ | ‘~=’ |
and | or
unop ::= ‘-’ | not | ‘#’
type ::= any | nil | basetype | uniontype | functiontype
basetype ::= boolean | number | string
uniontype ::= type ‘|’ type
functiontype ::= ‘(’ [typelist] ‘)’ ‘->’ ‘(’ [typelist] ‘)’
typelist ::= void | type {‘,’ type} [‘*’]

License

Released under the MIT License (MIT)

Copyright (c) 2013 Andre Murbach Maidl

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.