Error when setting `denote-journal-extras-title-format` to nil about denote

[protesilaos]

Thank you @tjstankus! I just pushed the changes. Please let me know if it now works for you.

[tjstankus]

Thank you for addressing this so quickly @protesilaos! Unfortunately, I'm still hitting the same issue after updating. To provide more context, I'm using doom-emacs and the denote-specific part of my config looks like this:

;; denote
(require 'denote)
(require 'denote-org-dblock)
(setq denote-directory (expand-file-name "~/Dropbox/org/denote"))
(require 'denote-journal-extras)
;; Set to nil to prompt for title
(setq denote-journal-extras-title-format nil)

In the meantime, there's a straightforward workaround:

• (setq denote-journal-extras-title-format 'day-date-month-year)
• edit file front matter
• denote-rename-file-using-front-matter

[protesilaos]

Oh, this is strange! Could it be that there was some old code kept around during your session and the new one will take effect upon restart? I can no longer reproduce the error: it works as expected on my end.

Screenshots below.

Ordinary prompt for title, with current date as the default value

User input at the prompt

The resulting buffer

[tjstankus]

Thanks @protesilaos! I'm still seeing the issue. Again, not a big deal because I can work around it like I mentioned. And it may very well be something in my config. I recorded this video showing the issue on my machine - maybe it will help. Thank you for your generous work on this package!

[protesilaos]

Thank you @tjstankus! I could not reproduce your issue, though I still rewrote the helper function. Here is its current implementation:

(defun denote-journal-extras-daily--title-format ()
  "Return `denote-journal-extras-title-format' or prompt for title."
  (format-time-string
   (if (and denote-journal-extras-title-format
            (stringp denote-journal-extras-title-format))
       denote-journal-extras-title-format
     (pcase denote-journal-extras-title-format
       ('day "%A")
       ('day-date-month-year "%A %e %B %Y")
       ('day-date-month-year-24h "%A %e %B %Y %H:%M")
       ('day-date-month-year-12h "%A %e %B %Y %I:%M %^p")
       (_ (denote-title-prompt (format-time-string "%F")))))))

I also wrote this test for it:

(ert-deftest denote-test--denote-journal-extras-daily--title-format ()
  "Make sure that `denote-journal-extras-daily--title-format' yields the desired format."
  (should (and
           ;; These three should prompt, but I am here treating the
           ;; prompt as if already returned a string.  The test for
           ;; the `denote-title-prompt' can be separate.
           (stringp
            (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
                      (denote-journal-extras-title-format nil))
              (denote-journal-extras-daily--title-format)))

           (stringp
            (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
                      (denote-journal-extras-title-format t))
              (denote-journal-extras-daily--title-format)))

           (stringp
            (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
                      (denote-journal-extras-title-format :some-arbitrary-keyword))
              (denote-journal-extras-daily--title-format)))

           ;; And these return the following values
           (string-match-p
            "\\<.*?\\>"
            (let ((denote-journal-extras-title-format 'day))
              (denote-journal-extras-daily--title-format)))

           (string-match-p
            "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\}"
            (let ((denote-journal-extras-title-format 'day-date-month-year))
              (denote-journal-extras-daily--title-format)))

           (string-match-p
            "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\} [0-9]\\{,2\\}:[0-9]\\{,2\\} \\<.*?\\>"
            (let ((denote-journal-extras-title-format 'day-date-month-year-12h))
              (denote-journal-extras-daily--title-format)))

           (string-match-p
            "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\} [0-9]\\{,2\\}:[0-9]\\{,2\\}"
            (let ((denote-journal-extras-title-format 'day-date-month-year-24h))
              (denote-journal-extras-daily--title-format))))))

You can try the test by checking if the following returns a non-nil value (a 0 still counts as non-nil):

(and
 ;; These three should prompt, but I am here treating the
 ;; prompt as if already returned a string.  The test for
 ;; the `denote-title-prompt' can be separate.
 (stringp
  (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
            (denote-journal-extras-title-format nil))
    (denote-journal-extras-daily--title-format)))

 (stringp
  (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
            (denote-journal-extras-title-format t))
    (denote-journal-extras-daily--title-format)))

 (stringp
  (cl-letf (((symbol-function 'denote-title-prompt) #'identity)
            (denote-journal-extras-title-format :some-arbitrary-keyword))
    (denote-journal-extras-daily--title-format)))

 ;; And these return the following values
 (string-match-p
  "\\<.*?\\>"
  (let ((denote-journal-extras-title-format 'day))
    (denote-journal-extras-daily--title-format)))

 (string-match-p
  "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\}"
  (let ((denote-journal-extras-title-format 'day-date-month-year))
    (denote-journal-extras-daily--title-format)))

 (string-match-p
  "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\} [0-9]\\{,2\\}:[0-9]\\{,2\\} \\<.*?\\>"
  (let ((denote-journal-extras-title-format 'day-date-month-year-12h))
    (denote-journal-extras-daily--title-format)))

 (string-match-p
  "\\<.*?\\> [0-9]\\{,2\\} \\<.*?\\> [0-9]\\{,4\\} [0-9]\\{,2\\}:[0-9]\\{,2\\}"
  (let ((denote-journal-extras-title-format 'day-date-month-year-24h))
    (denote-journal-extras-daily--title-format))))

[tjstankus]

@protesilaos I updated again and it works - thank you!

[protesilaos]

Very well! We can safely close this. Thank you!