Analyse dateTime/Period/date/time elements about certificator

[nir-r]

/*Analyse dateTime/Period/date/time elements https://github.com/users/nir-r/projects/1/views/1?pane=issue&itemId=66362143*/
/*List dateTime/Period/date/time elements in server-supported resources*/
(
  /*List all supported resources*/
   $SupportedResourceTypes := $capabilities().rest.resource[type in ['Patient','Practitioner','PractitionerRole','Observation','Encounter','Procedure']].type /*remove [] filtering on prod*/

  /*For each supported resource, list date/time/period elements*/
    ;$elements := $SupportedResourceTypes.$getSnapshot($).snapshot.element[type.code='dateTime' or type.code='date' or type.code='time' or type.code='Period'].{
      'resourceType': $substringBefore(path,".")
      ,'path': path
      ,'elementPath' : $substringAfter(path,$substringBefore(path,".") & '.')
      ,'id':id
      ,"dataType": type.code
      }

  /*Read sampled resources to memory*/
    ;$SampledResources := $readFile('SampledResources.json')

  /*Extract all values from date\time paths*/
    ;$DTvalues := $elements@$e.$SampledResources[$.resourceType=$e.resourceType].{
      'path':($e.path)
      ,'dataType':($e.dataType)
      ,'pathValue':$eval($e.elementPath)
      ,'id':$.id
      }
  
  /*Flatten the extracted values before loading to OLAP*/
  ;$DTvalues.{
    'path':path
    ,'dataType':dataType
    ,dataType='Period' ? {'pathValue.start':pathValue.start,'pathValue.end':pathValue.end} : 'pathValue':pathValue    
  }
)

[nir-r]

/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].(
      $instance := $;
      $value := $eval($dte.elementPath);
      $value#$i.{
      'resourceType': $instance.resourceType
      ,'id': $instance.id
      ,'path': $dte.path
      ,'dataType' : $dte.dataType
      ,'index': $i
      ,'value': $
      }
    ));
  
  $ElementsValues^(dataType,id,path,index)
)

[nir-r]

/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].{
    'resourceType': resourceType
    ,'id': id
    ,'path': $dte.path
    ,'dataType' : $dte.dataType
    ,'value': $eval($dte.elementPath)
    });
  
  $ElementsValues.value#$i.{
    'resourceType': %.resourceType
    ,'id': %.id
    ,'path': %.path
    ,'dataType' : %.dataType
    ,'index' : $i 
    ,'value': $
    }
)
```
/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].{
    'resourceType': resourceType
    ,'id': id
    ,'path': $dte.path
    ,'dataType' : $dte.dataType
    ,'value': $eval($dte.elementPath)
    });
  
  $ElementsValues.value#$i.{
    'resourceType': %.resourceType
    ,'id': %.id
    ,'path': %.path
    ,'dataType' : %.dataType
    ,'index' : $i 
    ,'value': $
    }
)