Body is not read if the body is in a different packet than the request headers about ocaml-cohttp

[talex5]

I don't see that on my machine. Here's a self-contained test-case that includes a test client:

open Eio.Std
open Cohttp

let addr = `Tcp (Eio.Net.Ipaddr.V4.any, 8080)

let header = "POST / HTTP/1.1\r\n\
Host: 127.0.0.1:8080\r\n\
User-Agent: curl/7.88.1\r\n\
Accept: */*\r\n\
Content-Length: 3\r\n\
Content-Type: application/x-www-form-urlencoded\r\n\
\r\n\
"

let run_client net =
  Switch.run @@ fun sw ->
  let conn = Eio.Net.connect ~sw net addr in
  Eio.Flow.write conn [Cstruct.of_string header];
  traceln "waiting...";
  Eio_unix.sleep 0.8;
  traceln "done";
  Eio.Flow.write conn [Cstruct.of_string "oo"];
  Eio.Flow.shutdown conn `Send;
  traceln "Got: %S" (Eio.Flow.read_all conn)

let () =
  let handler _env _conn _req body =
    let body = Eio.Flow.read_all body in
    Printf.printf "Body read with length: %i\n%!" (String.length body);
    ( Http.Response.make
        ~status:`OK
        ~headers:(Header.of_list [])
        (),
      Eio.Flow.string_source "" )
  in
  Eio_main.run @@ fun env ->
  Eio.Switch.run @@ fun sw ->
  let socket = Eio.Net.listen env#net ~sw ~backlog:128 ~reuse_addr:true addr
  and server = Cohttp_eio.Server.make ~callback:(handler env) () in
  let log_warning ex = Printf.eprintf "%s%!" (Printexc.to_string ex) in
  Fiber.both
    (fun () -> Cohttp_eio.Server.run socket server ~on_error:log_warning)
    (fun () -> run_client env#net)

Running that, I get:

+waiting...                       
+done
Body read with length: 2
+Got: "HTTP/1.1 200 OK\r\ntransfer-encoding: chunked\r\n\r\n0\r\n\r\n"

Does it work for you?

(I'm using cohttp-eio 6.0.0~beta2)

[wokalski]

I don't have a setup to test anymore. I'll close the issue for now, if I ever see it again, I will reopen it and run the repro.