term not clear . need proper documentation please about arduinoosc

[hideakitai]

  osc.addCallback("/ard/aaa", &callback);
  osc.addCallback("/ard", &callback);

These are the "callback" function, so if the OSC message comes and the address of OSC is "/ard/aaa" or "/ard", callback() will be called.

  //create new osc message
  OSCMessage msg;
  //set destination ip address & port no
  msg.beginMessage(host, send_port);
  //set argument
  msg.setOSCAddress(m.getOSCAddress());
  msg.addArgInt32(m.getArgAsInt32(0));
  msg.addArgFloat(m.getArgAsFloat(1));
  msg.addArgString(m.getArgAsString(2));
  //send osc message
  osc.send(msg);
  Serial.println("Sent OSC message");

And these are the sequence to send OSC message. You can make sendOSC() function like

void sendOSC()
{
  //create new osc message
  OSCMessage msg;
  //set destination ip address & port no
  msg.beginMessage(host, send_port);
  //set argument
  msg.setOSCAddress("/return");
  msg.addArgInt32(1);
  msg.addArgFloat(2.2);
  msg.addArgString("return message");
  //send osc message
  osc.send(msg);
  Serial.println("Sent OSC message");
}

and also you can set this function to callback function like

void callback(OSCMessage& m)
{
	sendOSC();
}

then you can get

#include <ArduinoOSC.h>

void setup()
{
    // various settings...
    
  osc.addCallback("/ard/aaa", &sendTest1); // if "/ard/aaa XXX" has come, sendTest1() will be called
  osc.addCallback("/ard", &sendTest2); // if "/ard XXX" has come, sendTest2() will be called
}

void loop()
{
  osc.parse();
}

void sendTest1(OSCMessage& m)
{
  //create new osc message
  OSCMessage msg;
  //set destination ip address & port no
  msg.beginMessage(host, send_port);
  //set argument
  msg.setOSCAddress("/return");
  msg.addArgInt32(1);
  msg.addArgFloat(2.2);
  msg.addArgString("test");
  //send osc message
  osc.send(msg);
  Serial.println("Sent OSC message");
}

void sendTest2(OSCMessage& m)
{
  //create new osc message
  OSCMessage msg;
  //set destination ip address & port no
  msg.beginMessage(host, send_port);
  //set argument
  msg.setOSCAddress("/test");
  msg.addArgInt32(3);
  msg.addArgFloat(4.4);
  msg.addArgString("test2");
  //send osc message
  osc.send(msg);
  Serial.println("Sent OSC message");
}

or you can just send OSC message in one second

#include <ArduinoOSC.h>

void setup()
{
    // various settings...

    // no callback definition
//  osc.addCallback("/ard/aaa", &callback);
//  osc.addCallback("/ard", &callback);
}

void loop()
{
    // just send current time in one second
    
    delay(1000);
    
    //create new osc message
    OSCMessage msg;
    //set destination ip address & port no
    msg.beginMessage(host, send_port);
    //set argument
    msg.setOSCAddress("/test");
    msg.addArgInt32(millis()); // millis
    msg.addArgFloat((float)millis() / 1000.f); // second
    msg.addArgString("second");
    //send osc message
    osc.send(msg);
    Serial.println("Sent OSC message");
}