[Bug]: Service object type from the service object typedesc does not have the annotations about ballerina-lang

[MaryamZi]

Modified the code to access relevant annotations.

import ballerina/io;

type AnnotRecord record {|
    string value;
|};

type AnnotRecord1 record {|
    typedesc value;
|};

annotation AnnotRecord annot on type;
annotation AnnotRecord1 annot1 on service, type;

@annot {
    value: "T1"
}
public type Service service object {
    resource function get pet() returns string ;
};

listener Listener lst = new Listener(9090);

@annot1 {
    value: Service
}
service Service on lst  {
    resource function get pet() returns  string {
        return  "string";
    }
}

public class Listener {
    int port;
    Service? s = ();
    public function 'start() returns error? {
        Service s = <Service> self.s;
        AnnotRecord1? annot = (typeof s).@annot1;
        io:println("start: ", annot);
        if annot is AnnotRecord1 {
            io:println(Service.@annot);
            io:println(annot.value.@annot);
        }
    }

    public function gracefulStop() returns error? {
    }

    public function immediateStop() returns error? {
    }

    public function detach(Service s) returns error? {
    }

    public function attach(Service s, string[]? name = ()) returns error? {
        self.s = s;
        AnnotRecord1? annot = (typeof s).@annot1;
        io:println("attach: ", annot);
        if annot is AnnotRecord1 {
            io:println(Service.@annot);
            io:println(annot.value.@annot);
        }
    }

    public function init(int port) {
        self.port = port;
    }
}

Running executable

attach: {"value":typedesc Service}


start: {"value":typedesc Service}
{"value":"T1"}
{"value":"T1"}

The annotation is available at start. Assuming this translates to native code also, is accessing annotations at start an option for now, @TharmiganK?

[chiranSachintha]

This issue occurs when a service calls the listener from the compiler before setting the annotations to the types. (We are not generating type descriptors for the service types. Therefore, we need to retain the annotations in the type for now). With the following example, we can generate the issue.

import ballerina/io;

type AnnotRecord record {|
    string value;
|};

type AnnotRecord1 record {|
    typedesc value;
|};

annotation AnnotRecord annot on type;
annotation AnnotRecord1 annot1 on service, type;



@annot {
    value: "T1"
}
public type Service service object {
    resource function get pet() returns string ;
};



listener Listener lst = new Listener(9090);

@annot1 {
    value: Service
}
service Service on lst  {
    resource function get pet() returns  string {
        return  "string";
    }
}

public class Listener {
    int port;
    public function 'start() returns error? {
    }

    public function gracefulStop() returns error? {
    }

    public function immediateStop() returns error? {
    }

    public function detach(service object {} s) returns error? {
    }

    public function attach(service object {} s, string[]? name = ()) returns error? {
        AnnotRecord1? annot = (typeof s).@annot1;
        io:println(annot);
        if annot is AnnotRecord1 {
            io:println((typeof Service).@annot1);
            io:println((typeof (annot.value)).@annot);
        }
    }

    public function init(int port) {
        self.port = port;
    }
}

[MaryamZi]

Is this a duplicate of #33594 then? Are they accessible in the start method?

We tried fixing the original issue back then, but deferred due to complexity of a workaround vs going with the typedesc change.

[TharmiganK]

The annotation is available at start. Assuming this translates to native code also, is accessing annotations at start an option for now?

Will check on this

[chiranSachintha]

Is this a duplicate of #33594 then? Are they accessible in the start method?

We tried fixing the original issue back then, but deferred due to complexity of a workaround vs going with the typedesc change.

Yes.

[TharmiganK]

@MaryamZi I moved the logic to start and the service level annotations are now present for the service types defined in the same package (if I defined the service type in a different package and import, the annotations are present in attach and start)

But the original issue is still there where I cannot get the resource level annotations. The following is a reduced ballerina code which represents my actual use case:

import ballerina/io;

type ResourceAnnotation record {
    string value;
};

type ParameterAnnotation record {
    string value;
};

type ServiceAnnotation record {
    string value?;
    typedesc<ServiceContract> serviceContractType?;
};

annotation ResourceAnnotation ResourceConfig on function;
annotation ParameterAnnotation ParamConfig on parameter;
annotation ServiceAnnotation ServiceConfig on service, type;

public type Service service object {
};

public type ServiceContract service object {
     *Service;
};

public type User record {|
    int id;
    string name;
    string email;
|};

@ServiceConfig {
    value: "users-service-contract"
}
public type UsersService service object {
    *ServiceContract;

    @ResourceConfig {value: "get-users"}
    resource function post users(@ParamConfig {value: "payload-param"} User user) returns User|error;
};

public class Listener {

    Service? s = ();

    public function 'start() returns error? {
        ServiceAnnotation? serviceConfig = (typeof self.s).@ServiceConfig;
        io:println("self-start: ", serviceConfig);
        if serviceConfig is ServiceAnnotation {
            io:println("self-start: ", UsersService.@ServiceConfig);
            typedesc<ServiceContract>? serviceContractType = serviceConfig.serviceContractType;
            io:println("self-start: ", serviceContractType);
            if serviceContractType is typedesc<ServiceContract> {
                io:println("self-start: ", serviceContractType.@ServiceConfig);
            }
        }
        // Need to access the resource level and resource parameter level annotations here
    }

    public function gracefulStop() returns error? {
    }

    public function immediateStop() returns error? {
    }

    public function detach(Service s) returns error? {
    }

    public function attach(Service s, string[]? name = ()) returns error? {
        self.s = s;
        ServiceAnnotation? serviceConfig = (typeof s).@ServiceConfig;
        io:println("self-attach: ", serviceConfig);
        if serviceConfig is ServiceAnnotation { 
            io:println("self-attach: ", UsersService.@ServiceConfig);
            typedesc<ServiceContract>? serviceContractType = serviceConfig.serviceContractType;
            io:println("self-attach: ", serviceContractType);
            if serviceContractType is typedesc<ServiceContract> {
                io:println("self-attach: ", serviceContractType.@ServiceConfig);
            }
        }
    }

    public function init(int port) {
    }
}

@ServiceConfig {
    serviceContractType: UsersService
}
service UsersService on new Listener(8080) {
    resource function post users(User user) returns User|error {
        return user;
    }
}

Note: Please note the resource level and resource parameter level annotations in the service contract type - UsersService

[chiranSachintha]

This is a bug in the compiler. The issue is that we added those annotations to the annotation map, but at runtime, we didn't apply these annotations to the type associated with the resource functions and parameters. We only set the annotations which attached to the service type. (As a solution, we need to add those annotations to their respective types by calling the processAnnotation function.) @MaryamZi

[MaryamZi]

Seems to be an issue at runtime rather.

The check at https://github.com/ballerina-platform/ballerina-lang/blob/v2201.9.2/bvm/ballerina-runtime/src/main/java/io/ballerina/runtime/internal/AnnotationUtils.java#L61 is no longer sufficient with type reference types.

[MaryamZi]

Let's use

• #33594 to track the original issue and
• #43122 to track the new issue (tagging this for U10)

[MaryamZi]

Let's use

• Annotation doesn't get populated before listener init #33594 to track the original issue and
• Method annotations not available on object type descriptors #43122 to track the new issue (tagging this for U10)

Closing this since this was/is tracked in other issues.

[github-actions]

This issue is NOT closed with a proper Reason/ label. Make sure to add proper reason label before closing. Please add or leave a comment with the proper reason label now.

      - Reason/EngineeringMistake - The issue occurred due to a mistake made in the past.
      - Reason/Regression - The issue has introduced a regression.
      - Reason/MultipleComponentInteraction - Issue occured due to interactions in multiple components.
      - Reason/Complex - Issue occurred due to complex scenario.
      - Reason/Invalid - Issue is invalid.
      - Reason/Other - None of the above cases.